ArduinoでRFID NFCリーダーを使う簡単コード

ArduinoでRFIDリーダーを使う

初心者でもわかる。ArduinoのRFIDリーダーの設定の仕方を超早わかり

ハードウェアを使ったある種の認証形態をプロジェクトに利用したいと思っているなら、この基盤を使ってみて下さい。パララックスRFID（電波による個体識別）リーダーの設定は、配線が４ヶ所だけで、ものすごく簡単です。ArduinoにRFIDカードからの情報を転送するためにシリアル・プロトコルを使います。今回は、Arudinoのシステムでの、このRFIDリーダーの使用を簡単に解説します。

ステップ１

まずは必要なコンポーネントを集める簡単なステップから始めましょう。必要なものは；

ジャンパーワイヤー４本
パララックスRFIDリーダー
Arduino開発ボード
ブレッドボード（オプション）
それだけです。では、次のステップへ…

ステップ2

RFIDリーダーとArduinoを下記のピンマッピングの要領で配線します。
Arduino Rx = RFID S_OUT
Arduino D2 = RFID Enable
Arduino GND = RFID GND
Arduino 5v = RFID V_CC
D2はデジタルピン番号2番です。

ステップ３

Arduinoにコードを書き込みます。
RFIDへの多種多彩なAnduinoコードがありますが、現在、確認した中ではベンジャミン・エッケルによるコードが一番です。コメントを日本語かして保管資料として彼のコードを載せておきます。

/**
 * author Benjamin Eckel
 * date 10-17-2009
 *
 * Minor edits by Riley Porter
 * 2-27-2011
 */
#define RFID_ENABLE 2   //RFID を利用可能にする
#define CODE_LEN 10      //RFID タグの文字列の最大値を設定
#define VALIDATE_TAG 1  //tagをゆうこうかすべき
#define VALIDATE_LENGTH  200 //maximum reads b/w tag read and validate
#define ITERATION_LENGTH 2000 //時間, in ミリ秒, ユーザが自分で調整する
#define START_BYTE 0x0A 
#define STOP_BYTE 0x0D
 
char tag[CODE_LEN];  
 
void setup() { 
  Serial.begin(2400);  
  pinMode(RFID_ENABLE,OUTPUT);   
}
 
void loop() {   //main Arduino Loopの開始
  enableRFID();   //RFIDカードの利用を可能にする
  getRFIDTag();   //タグを読むn
  if(isCodeValid()) {  //タグが有効か確認する
    disableRFID();  //RFIDをlow power modeにする。
    sendCode();     //コードをシリアルポートに送信
    delay(ITERATION_LENGTH);  //デバウンス?
  } else {
    disableRFID();  //不完全なコードの場合.. 
    Serial.println("ノイズを検知しました");

  }
  Serial.flush();
  clearCode();
} 
 
/**
 * メモリースペースを空にする。 */
void clearCode() {
  for(int i=0; i<CODE_LEN; i++) {
    tag[i] = 0; 
  }
}
 
/**
 * タグをパソコンに送信する
 */ 
void sendCode() {
  //変数（コード）が有効か確認するためにここにreturnを加えた。

Serial.print("TAG:");  

    char full_tag[10];
    for(int i=0; i<CODE_LEN; i++) {

      if (i == 9)  //Edits by riley porter
        Serial.println(tag[i]);  //最後のバイト数かどうかここで確認する

      else                       //これがもし新しい行を出力するならコードがごちゃごちゃになる
        Serial.print(tag[i]);  
      
    } 
}
 
/**************************************************************/
/********************   RFID Functions  ***********************/
/**************************************************************/
 
void enableRFID() {
   digitalWrite(RFID_ENABLE, LOW);    
}
 
void disableRFID() {
   digitalWrite(RFID_ENABLE, HIGH);  
}
 
/**
 * ブロックする function, RFID tag停止してからRFIDを読む.
 */
void getRFIDTag() {
  byte next_byte; 
  while(Serial.available() <= 0) {}
  if((next_byte = Serial.read()) == START_BYTE) {      
    byte bytesread = 0; 
    while(bytesread < CODE_LEN) {
      if(Serial.available() > 0) { //wait for the next byte
          if((next_byte = Serial.read()) == STOP_BYTE) break;       
          tag[bytesread++] = next_byte;                   
      }
    }                
  }    
}
 
/**
 * 次のタグが現在のタグと合致するか見るために一時停止する

 */
boolean isCodeValid() {
  byte next_byte; 
  int count = 0;
  while (Serial.available() < 2) {  //there is already a STOP_BYTE in buffer
    delay(1); //probably not a very pure millisecond
    if(count++ > VALIDATE_LENGTH) return false;
  }
  Serial.read(); //throw away extra STOP_BYTE
  if ((next_byte = Serial.read()) == START_BYTE) {  
    byte bytes_read = 0; 
    while (bytes_read < CODE_LEN) {
      if (Serial.available() > 0) { //wait for the next byte      
          if ((next_byte = Serial.read()) == STOP_BYTE) break;
          if (tag[bytes_read++] != next_byte) return false;                     
      }
    }                
  }
  return true;   
}

この時点で、RFIDリーダーはArduinoと通信でき、コードをいつでもハックすることができます。ご自分で素敵なプロジェクトを作ってみましょう。
ターミナルにタグをプリントする以外にRFIDリーダーを使用するためにハックするのがsendCode機能です。完全にコードを理解するには、データシートをすべて読んで下さい。こちらからダウンロードして下さい.